libtorrent-rasterbar/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3 # Contributor: Hugo Doria <hugo@archlinux.org>
   4
   5 pkgname=libtorrent-rasterbar
   6 pkgver=2.0.6
   7 pkgrel=2
   8 epoch=1
   9 pkgdesc="A C++ BitTorrent library that aims to be a good alternative to all the other implementations around"
  10 url="https://www.rasterbar.com/products/libtorrent/"
  11 arch=('x86_64')
  12 license=('BSD')
  13 depends=('boost-libs' 'openssl')
  14 makedepends=('boost' 'cmake' 'ninja' 'python-setuptools')
  15 options=('!emptydirs')
  16 source=(https://github.com/arvidn/libtorrent/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz)
  17 sha512sums=('4a5d710706040ef6193967dbb13998cb0ddebe7e95c3bf8aec0812876027c68c32b001fd3f07cd4ff1b819660a8d46ae8c7077e72caf92572288a51cdec7daea')
  18
  19 prepare() {
  20   mkdir -p build
  21 }
  22
  23 build() {
  24   cd build
  25   cmake -DCMAKE_BUILD_TYPE=Release \
  26     -DCMAKE_INSTALL_PREFIX="/usr" \
  27     -DCMAKE_INSTALL_LIBDIR="lib" \
  28     -Dpython-bindings=ON \
  29     -Dboost-python-module-name="python" \
  30     -Dpython-egg-info=ON \
  31     -GNinja ../$pkgname-$pkgver
  32   ninja
  33 }
  34
  35 package() {
  36   cd build
  37   DESTDIR="$pkgdir" ninja install
  38   install -Dm644 ../$pkgname-$pkgver/COPYING -t "$pkgdir"/usr/share/licenses/$pkgname/
  39 }