libuv/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Massimiliano Torromeo <massimiliano.torromeo@gmail.com>
   3
   4 pkgname=libuv
   5 pkgver=1.43.0
   6 pkgrel=1
   7 pkgdesc="Multi-platform support library with a focus on asynchronous I/O"
   8 arch=('x86_64')
   9 url="https://github.com/libuv/libuv"
  10 license=('custom')
  11 depends=('glibc' 'libnsl')
  12 makedepends=('python-sphinx')
  13 source=(https://dist.libuv.org/dist/v$pkgver/libuv-v$pkgver.tar.gz{,.sign})
  14 sha512sums=('ba48140ac5733e09462a731fe9194c902b011a1a93a63175949c616367bde56bd1c114e8487c5580bee2d4656b45ab8cdc4fc335f67dd35e793c1a943f69fb34'
  15             'SKIP')
  16 # PGP key IDs are available from https://github.com/libuv/libuv/blob/v1.x/MAINTAINERS.md
  17 validpgpkeys=('57353E0DBDAAA7E839B66A1AFF47D5E4AD8B4FDC'  # Colin Ihrig (@cjihrig)
  18               'AEAD0A4B686767751A0E4AEF34A25FB128246514') # Jameson Nash (@vtjnash)
  19
  20 build() {
  21     cd $pkgname-v$pkgver
  22     ./autogen.sh
  23     ./configure --prefix=/usr
  24     make
  25     make man -C docs
  26 }
  27
  28 check() {
  29     cd $pkgname-v$pkgver
  30     make check
  31 }
  32
  33 package() {
  34     cd $pkgname-v$pkgver
  35
  36     make DESTDIR="$pkgdir" install
  37
  38     install -Dm644 LICENSE \
  39         "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  40     install -Dm644 AUTHORS \
  41         "$pkgdir"/usr/share/doc/$pkgname/AUTHORS
  42     install -Dm644 README.md \
  43         "$pkgdir"/usr/share/doc/$pkgname/README.md
  44     install -Dm644 ChangeLog \
  45         "$pkgdir"/usr/share/doc/$pkgname/ChangeLog
  46     install -Dm644 docs/build/man/libuv.1 \
  47         "$pkgdir"/usr/share/man/man1/libuv.1
  48 }