w3m/trunk/PKGBUILD

   1 # Maintainer: Gaetan Bisson <bisson@archlinux.org>
   2 # Contributor: dorphell <dorphell@archlinux.org>
   3
   4 pkgname=w3m
   5 _gitcommit=30486718c5512fef115b01a235a05dad45d4328c
   6 _pkgver=0.5.3.git20220409-1
   7 pkgver=${_pkgver/-/_}
   8 pkgrel=1
   9 pkgdesc='Text-based Web browser as well as pager'
  10 url='https://salsa.debian.org/debian/w3m'
  11 license=('custom')
  12 arch=('x86_64')
  13 makedepends=('git' 'imlib2')
  14 optdepends=('imlib2: for graphics support')
  15 depends=('openssl' 'gc' 'ncurses' 'gpm')
  16 source=("git+https://salsa.debian.org/debian/w3m.git#commit=${_gitcommit}")
  17 sha256sums=('SKIP')
  18
  19 # There's also the maintainer's github repo, usually in sync with Debian's:
  20 # https://github.com/tats/w3m
  21
  22 build() {
  23         cd "${srcdir}/${pkgname}"
  24         ./configure \
  25                 --prefix=/usr \
  26                 --libexecdir=/usr/lib \
  27                 --enable-image=x11,fb \
  28                 --with-imagelib=imlib2 \
  29                 --with-termlib=ncurses \
  30                 --disable-w3mmailer \
  31
  32         make
  33 }
  34
  35 package() {
  36         cd "${srcdir}/${pkgname}"
  37         make DESTDIR="${pkgdir}" install
  38
  39         install -d "${pkgdir}"/usr/share/{doc,licenses}/w3m
  40         install -m644 doc/* "${pkgdir}/usr/share/doc/w3m"
  41         ln -s ../../doc/w3m/README "${pkgdir}/usr/share/licenses/w3m"
  42 }