xfce4-xkb-plugin/trunk/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: AndyRTR <andyrtr@archlinux.org>
   3 # Contributor: Tobias Kieslich <tobias (at) archlinux.org>
   4
   5 pkgname=xfce4-xkb-plugin
   6 pkgver=0.8.2
   7 pkgrel=1
   8 pkgdesc="Plugin to switch keyboard layouts for the Xfce4 panel"
   9 arch=('x86_64')
  10 url="https://docs.xfce.org/panel-plugins/xfce4-xkb-plugin"
  11 license=('custom')
  12 groups=('xfce4-goodies')
  13 depends=('xfce4-panel' 'libxklavier' 'librsvg' 'libwnck3')
  14 makedepends=('intltool')
  15 install=$pkgname.install
  16 source=(https://archive.xfce.org/src/panel-plugins/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2)
  17 sha256sums=('bb4be13f6f73cd86a6d939e1a6b125841cf266415bc4fd134a511e4f0cf97967')
  18
  19 build() {
  20   cd "$srcdir/$pkgname-$pkgver"
  21
  22   ./configure \
  23     --prefix=/usr \
  24     --sysconfdir=/etc \
  25     --libexecdir=/usr/lib \
  26     --localstatedir=/var \
  27     --disable-static \
  28     --disable-debug
  29   make
  30 }
  31
  32 package() {
  33   cd "$srcdir/$pkgname-$pkgver"
  34   make DESTDIR="$pkgdir" install
  35   install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  36 }
  37
  38 # vim:set ts=2 sw=2 et: