zziplib/trunk/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@gmail.com>
   2 # Contributor: Rémy Oudompheng <remy@archlinux.org>
   3 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   4 # Contributor: Roman Kyrylych <Roman.Kyrylych@gmail.com>
   5
   6 pkgname=zziplib
   7 pkgver=0.13.72
   8 pkgrel=1
   9 pkgdesc="A lightweight library that offers the ability to easily extract data from files archived in a single zip file"
  10 arch=('x86_64')
  11 url="http://zziplib.sourceforge.net"
  12 license=('LGPL' 'MPL')
  13 depends=('zlib')
  14 makedepends=('python' 'xmlto' 'zip' 'cmake' 'ninja')
  15 checkdepends=('unzip')
  16 source=($pkgname-$pkgver.tar.gz::"https://github.com/gdraheim/zziplib/archive/v$pkgver.tar.gz")
  17 sha512sums=('4bb089e74813c6fac9657cd96e44e4a6469bf86aba3980d885c4573e8db45e74fd07bbdfcec9f36297c72227c8c0b2c37dab1bc4326cef8529960e482fe501c8')
  18
  19 build() {
  20   cd ${pkgname}-${pkgver}
  21   cmake \
  22     -Bbuild \
  23     -GNinja \
  24     -DZZIPDOCS=OFF \
  25     -DCMAKE_INSTALL_PREFIX=/usr
  26   ninja -C build
  27 }
  28
  29 check() {
  30   cd ${pkgname}-${pkgver}
  31   ninja -C build check
  32 }
  33
  34 package() {
  35   cd ${pkgname}-${pkgver}
  36   DESTDIR="${pkgdir}" ninja -C build install
  37 }
  38
  39 # vim: set ts=2 sw=2 et: