librsvg/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgbase=librsvg
   5 pkgname=(librsvg librsvg-docs)
   6 pkgver=2.56.0
   7 pkgrel=1
   8 epoch=2
   9 pkgdesc="SVG rendering library"
  10 url="https://wiki.gnome.org/Projects/LibRsvg"
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(
  14   cairo
  15   freetype2
  16   gdk-pixbuf2
  17   glib2
  18   harfbuzz
  19   libxml2
  20   pango
  21 )
  22 makedepends=(
  23   gi-docgen
  24   git
  25   gobject-introspection
  26   python-docutils
  27   rust
  28   vala
  29 )
  30 checkdepends=(ttf-dejavu)
  31 _commit=b831e077174ae608d8cd09e532fc0e7ce1fe5c4f  # tags/2.56.0^0
  32 source=("git+https://gitlab.gnome.org/GNOME/librsvg.git#commit=$_commit")
  33 sha256sums=('SKIP')
  34
  35 pkgver() {
  36   cd librsvg
  37   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  38 }
  39
  40 prepare() {
  41   cd librsvg
  42   NOCONFIGURE=1 ./autogen.sh
  43 }
  44
  45 # Use LTO
  46 export CARGO_PROFILE_RELEASE_LTO=true CARGO_PROFILE_RELEASE_CODEGEN_UNITS=1
  47
  48 # Use debug
  49 export CARGO_PROFILE_RELEASE_DEBUG=2
  50
  51 build() {
  52   cd librsvg
  53   ./configure --prefix=/usr --disable-static --enable-vala --enable-gtk-doc
  54   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' libtool
  55   make
  56 }
  57
  58 check() {
  59   # Test suite is very dependent on the versions of
  60   # Cairo, Pango, FreeType and HarfBuzz
  61   make -C librsvg check || :
  62 }
  63
  64 package_librsvg() {
  65   provides=(librsvg-${pkgver%%.*}.so)
  66
  67   make -C librsvg DESTDIR="$pkgdir" install
  68
  69   mkdir -p doc/usr/share
  70   mv {"$pkgdir",doc}/usr/share/doc
  71 }
  72
  73 package_librsvg-docs() {
  74   pkgdesc+=" (documentation)"
  75   depends=()
  76
  77   mv doc/* "$pkgdir"
  78 }
  79
  80 # vim:set sw=2 sts=-1 et: