libsamplerate/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Eric Bélanger <eric@archlinux.org>
   3
   4 pkgname=libsamplerate
   5 pkgver=0.2.2
   6 pkgrel=2
   7 pkgdesc="An audio sample rate conversion library"
   8 arch=(x86_64)
   9 url="https://libsndfile.github.io/libsamplerate/"
  10 license=(BSD)
  11 depends=(glibc)
  12 makedepends=(alsa-lib cmake libsndfile opus)
  13 checkdepends=(fftw)
  14 provides=(libsamplerate.so)
  15 source=(https://github.com/libsndfile/$pkgname/releases/download/$pkgver/$pkgname-$pkgver.tar.xz{,.sig})
  16 sha512sums=('d23ae54d23209ba22baae9e5fd178dd8e0e99205dada7e7c3a7b3a3d8cf816ed427a411bfeb008427f64da7767d645edce40811f238af11c8c386f5ef25a9f0c'
  17             'SKIP')
  18 b2sums=('71b1e8a1644a94fff019abc6bf98c557df84994293f1e9bc651ad3ad3f0afeb24f54b8c75fc26e5202ae7c3a3e34e783fd1be7f7c6fdefe9eac9a5dfe7100b91'
  19         'SKIP')
  20 validpgpkeys=('31D95CAB6D80D262244A1750A47620E801E47E95')  # David Seifert soap@gentoo.org
  21
  22 build() {
  23   local cmake_options=(
  24     -B build
  25     -D CMAKE_INSTALL_PREFIX=/usr
  26     -D CMAKE_BUILD_TYPE=None
  27     -D BUILD_SHARED_LIBS=ON
  28     -S $pkgname-$pkgver
  29     -Wno-dev
  30   )
  31
  32   cmake "${cmake_options[@]}"
  33   cmake --build build --verbose
  34 }
  35
  36 check() {
  37   ctest --test-dir build --output-on-failure
  38 }
  39
  40 package() {
  41   DESTDIR="$pkgdir" cmake --install build
  42   install -vDm 644 $pkgname-$pkgver/{AUTHORS,NEWS,README.md,ChangeLog} -t "$pkgdir/usr/share/doc/$pkgname/"
  43   install -vDm 644 $pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
  44 }