xf86-video-ati/trunk/PKGBUILD

   1 # Maintainer: AndyRTR <andyrtr@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Alexander Baldeck <alexander@archlinux.org>
   4
   5 pkgname=xf86-video-ati
   6 pkgver=22.0.0
   7 pkgrel=1
   8 epoch=1
   9 pkgdesc="X.org ati video driver"
  10 arch=('x86_64')
  11 url="https://xorg.freedesktop.org/"
  12 license=('custom')
  13 depends=('systemd-libs' 'mesa')
  14 makedepends=('xorg-server-devel' 'systemd' 'X-ABI-VIDEODRV_VERSION=25.2') # 'git')
  15 conflicts=('xorg-server<21.1.1' 'X-ABI-VIDEODRV_VERSION<25' 'X-ABI-VIDEODRV_VERSION>=26')
  16 groups=('xorg-drivers')
  17 source=(${url}/releases/individual/driver/${pkgname}-${pkgver}.tar.xz{,.sig})
  18 sha512sums=('fba9ffc7b0eeb0c369eb1a6f8ef0bb3061cfeca26bc269baf6e3d16dcd943fbf4092f1e37adfb1bc71051cee0b7a0e6fb253f0b8bcd210732ccaf99e8f2356fe'
  19             'SKIP')
  20 #validpgpkeys=('B09FAF35BE914521980951145A81AF8E6ADBB200') # Michel Daenzer <michel@daenzer.net>
  21 validpgpkeys=('3BB639E56F861FA2E86505690FDD682D974CA72A') # Matt Turner <mattst88@gmail.com>
  22
  23 build() {
  24   cd ${pkgname}-${pkgver}
  25
  26 #  CFLAGS+=' -fcommon' # https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
  27
  28   # Since pacman 5.0.2-2, hardened flags are now enabled in makepkg.conf
  29   # With them, module fail to load with undefined symbol.
  30   # See https://bugs.archlinux.org/task/55102 / https://bugs.archlinux.org/task/54845
  31   export CFLAGS=${CFLAGS/-fno-plt}
  32   export CXXFLAGS=${CXXFLAGS/-fno-plt}
  33   export LDFLAGS=${LDFLAGS/,-z,now}
  34
  35   ./configure --prefix=/usr
  36   make
  37 }
  38
  39 check() {
  40   cd ${pkgname}-${pkgver}
  41   make check
  42 }
  43
  44 package() {
  45   cd ${pkgname}-${pkgver}
  46
  47   make "DESTDIR=${pkgdir}" install
  48   install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  49   install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
  50 }