tpm2-tss/trunk/PKGBUILD

   1 # Maintainer: Jonas Witschel <diabonas@archlinux.org>
   2 # Contributor: Bruno Pagani <archange@archlinux.org>
   3 pkgname=tpm2-tss
   4 pkgver=3.2.0
   5 pkgrel=3
   6 pkgdesc='Implementation of the TCG Trusted Platform Module 2.0 Software Stack (TSS2)'
   7 arch=('x86_64')
   8 url='https://github.com/tpm2-software/tpm2-tss'
   9 license=('BSD')
  10 depends=('curl' 'json-c' 'openssl' 'libjson-c.so')
  11 makedepends=('cmocka' 'doxygen' 'libtpms')
  12 checkdepends=('iproute2' 'swtpm' 'uthash')
  13 provides=('libtss2-esys.so' 'libtss2-fapi.so' 'libtss2-mu.so' 'libtss2-rc.so' 'libtss2-sys.so' 'libtss2-tctildr.so')
  14 backup=('etc/tpm2-tss/fapi-config.json'
  15         'etc/tpm2-tss/fapi-profiles/P_ECCP256SHA256.json'
  16         'etc/tpm2-tss/fapi-profiles/P_RSA2048SHA256.json')
  17 options=('!emptydirs' '!lto')
  18 source=("$url/releases/download/$pkgver/$pkgname-$pkgver.tar.gz"{,.asc}
  19         'https://raw.githubusercontent.com/tpm2-software/tpm2-tss/e237e4d33cbf280292a480edd8ad061dcd3a37a2/lib/tss2-tcti-libtpms.map')
  20 sha512sums=('cabb411f074dfa94919ba914849aac77a0ac2f50622e28a1406cf575369148774748e0e2b7a7c566ec83561a96d4b883bac5a3b1763f4cf48668a0c5d68c0a23'
  21             'SKIP'
  22             '55be966eb320c96ca49b3aaa0635815076fe1a21149d1a0f95654778c8359bd16f18a10c0cabe955a366d4a14e2645a8150878b601085d987727de40831e50ab')
  23 validpgpkeys=('D6B4D8BAC7E0CC97DCD4AC7272E88B53F7A95D84'  # Andreas Fuchs <andreas.fuchs@sit.fraunhofer.de>
  24               '5B482B8E3E19DA7C978E1D016DE2E9078E1F50C1') # William Roberts (Bill Roberts) <william.c.roberts@intel.com>
  25
  26 prepare() {
  27         cd "$pkgname-$pkgver"
  28         # Add file missing from release tarball (https://github.com/tpm2-software/tpm2-tss/issues/2313)
  29         cp "$srcdir/tss2-tcti-libtpms.map" lib
  30 }
  31
  32 build() {
  33         cd "$pkgname-$pkgver"
  34         ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  35                     --with-runstatedir=/run --with-sysusersdir=/usr/lib/sysusers.d \
  36                     --with-tmpfilesdir=/usr/lib/tmpfiles.d --with-udevrulesprefix=60- \
  37                     --enable-unit $( ((CHECKFUNC)) && echo --enable-integration)
  38         make
  39 }
  40
  41 check() {
  42         cd "$pkgname-$pkgver"
  43         make check
  44 }
  45
  46 package() {
  47         cd "$pkgname-$pkgver"
  48         make DESTDIR="$pkgdir" install
  49         install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  50 }