libnl/trunk/PKGBUILD

   1 # Maintainer:  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   2 # Contributor: Thomas Bächler <thomas@archlinux.org>
   3
   4 pkgname=libnl
   5 pkgver=3.7.0
   6 pkgrel=3
   7 pkgdesc='Library for applications dealing with netlink sockets'
   8 arch=('x86_64')
   9 url='https://github.com/thom311/libnl/'
  10 license=('GPL')
  11 depends=('glibc' 'gcc-libs')
  12 provides=('libnl-3.so' 'libnl-cli-3.so' 'libnl-genl-3.so' 'libnl-idiag-3.so'
  13           'libnl-nf-3.so' 'libnl-route-3.so' 'libnl-xfrm-3.so')
  14 backup=('etc/libnl/classid'
  15         'etc/libnl/pktloc')
  16 validpgpkeys=('49EA7C670E0850E7419514F629C2366E4DFC5728') # Thomas Haller
  17 source=("https://github.com/thom311/libnl/releases/download/libnl${pkgver//./_}/${pkgname}-${pkgver}.tar.gz"{,.sig})
  18 sha256sums=('9fe43ccbeeea72c653bdcf8c93332583135cda46a79507bfd0a483bb57f65939'
  19             'SKIP')
  20
  21 build() {
  22   cd $pkgname-$pkgver
  23   ./configure \
  24     --prefix=/usr \
  25     --sysconfdir=/etc \
  26     --sbindir=/usr/bin \
  27     --disable-static
  28   make
  29 }
  30
  31 check() {
  32   make -C $pkgname-$pkgver check
  33 }
  34
  35 package() {
  36   make -C $pkgname-$pkgver DESTDIR="$pkgdir" install
  37 }