libva/trunk/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Ionut Biru <ibiru@archlinux.org>
   4
   5 pkgname=libva
   6 pkgver=2.18.0
   7 pkgrel=1
   8 pkgdesc='Video Acceleration (VA) API for Linux'
   9 arch=(x86_64)
  10 url=https://01.org/linuxmedia/vaapi
  11 license=(MIT)
  12 depends=(
  13   libdrm
  14   libgl
  15   libx11
  16   libxext
  17   libxfixes
  18   wayland
  19 )
  20 makedepends=(
  21   git
  22   libglvnd
  23   mesa
  24   meson
  25 )
  26 optdepends=(
  27   'intel-media-driver: backend for Intel GPUs (>= Broadwell)'
  28   'libva-intel-driver: backend for Intel GPUs (<= Haswell)'
  29   'libva-mesa-driver: backend for AMD and Nvidia GPUs'
  30 )
  31 provides=(
  32   libva-drm.so
  33   libva-glx.so
  34   libva-wayland.so
  35   libva-x11.so
  36   libva.so
  37 )
  38 backup=(etc/libva.conf)
  39 _tag=b06ccb323cd68bc5ce3fa9861c831766d6355d88
  40 source=(git+https://github.com/intel/libva.git#tag=${_tag})
  41 sha256sums=('SKIP')
  42
  43 pkgver() {
  44   cd libva
  45   git describe --tags
  46 }
  47
  48 build() {
  49   CFLAGS+=" -DENABLE_VA_MESSAGING" # Option missing
  50   arch-meson libva build
  51   meson compile -C build
  52 }
  53
  54 package() {
  55   meson install -C build --destdir "${pkgdir}"
  56   install -Dm 644 libva/COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}
  57   install -Dm 644 /dev/stdin "${pkgdir}"/etc/libva.conf <<END
  58 LIBVA_MESSAGING_LEVEL=1
  59 END
  60 }
  61
  62 # vim: sw=2 ts=2 et: