pavucontrol/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   3 # Contributor: Corrado Primier <bardo@aur.archlinux.org>
   4 # Contributor: William Rea <sillywilly@gmail.com>
   5
   6 pkgname=pavucontrol
   7 pkgver=5.0+r61+gee77d86
   8 pkgrel=2
   9 epoch=1
  10 pkgdesc="PulseAudio Volume Control"
  11 url="https://freedesktop.org/software/pulseaudio/pavucontrol/"
  12 arch=(x86_64)
  13 license=(GPL)
  14 depends=(gtkmm3 libsigc++ libcanberra json-glib)
  15 makedepends=(meson lynx git)
  16 checkdepends=(tidy)
  17 optdepends=("pulseaudio: Audio backend")
  18 _commit=ee77d86eed3c35f9f7a1f2e2da385d4b526d77a1  # master
  19 source=("git+https://gitlab.freedesktop.org/pulseaudio/pavucontrol.git#commit=$_commit")
  20 sha256sums=('SKIP')
  21
  22 pkgver() {
  23   cd pavucontrol
  24   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd pavucontrol
  29 }
  30
  31 build() {
  32   arch-meson pavucontrol build
  33   meson compile -C build
  34 }
  35
  36 check() {
  37   meson test -C build --print-errorlogs
  38 }
  39
  40 package() {
  41   meson install -C build --destdir "$pkgdir"
  42 }