adwaita-icon-theme/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Lukas Fleischer <lfleischer@archlinux.org>
   3 # Contributor: Jan de Groot <jgc@archlinux.org>
   4
   5 pkgname=adwaita-icon-theme
   6 pkgver=43
   7 pkgrel=1
   8 pkgdesc="GNOME standard icons"
   9 url="https://gitlab.gnome.org/GNOME/adwaita-icon-theme"
  10 arch=(any)
  11 license=(LGPL3 CCPL:by-sa)
  12 depends=(hicolor-icon-theme gtk-update-icon-cache librsvg)
  13 makedepends=(git gtk3)
  14 _commit=3ea65342a846b2b29fe6feedcd13e2ecc5b5c2b2  # tags/43^0
  15 source=("git+https://gitlab.gnome.org/GNOME/adwaita-icon-theme.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25   autoreconf -fvi
  26 }
  27
  28 build() {
  29   cd $pkgname
  30   ./configure --prefix=/usr
  31   make
  32 }
  33
  34 check() {
  35   cd $pkgname
  36   make check
  37 }
  38
  39 package() {
  40   cd $pkgname
  41   make DESTDIR="$pkgdir" install
  42 }