akonadi/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   4 # Contributor: Pierre Schmitz <pierre@archlinux.de>
   5
   6 pkgbase=akonadi
   7 pkgname=(akonadi libakonadi)
   8 pkgver=22.08.2
   9 pkgrel=1
  10 pkgdesc='PIM layer, which provides an asynchronous API to access all kind of PIM data'
  11 arch=(x86_64)
  12 url='https://kontact.kde.org'
  13 license=(LGPL)
  14 makedepends=(extra-cmake-modules postgresql qt5-tools kitemmodels kaccounts-integration doxygen)
  15 source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz{,.sig})
  16 sha256sums=('2632085006b140a11035955b51d65339154c1af461960751b149851a5b62d457'
  17             'SKIP')
  18 validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
  19               F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck@kde.org>
  20               D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker@kde.org>
  21 options=(debug)
  22
  23 build() {
  24   cmake -B build -S $pkgname-$pkgver \
  25     -DBUILD_TESTING=OFF \
  26     -DBUILD_QCH=ON
  27   cmake --build build
  28 }
  29
  30 package_libakonadi() {
  31   pkgdesc='Libraries used by applications based on Akonadi'
  32   depends=(kitemmodels kaccounts-integration)
  33
  34   DESTDIR="$pkgdir" cmake --install build
  35   rm -r "$pkgdir"/usr/bin # Provided by akonadi
  36 }
  37
  38 package_akonadi() {
  39   depends=(libakonadi mariadb)
  40   optdepends=('postgresql: PostgreSQL backend')
  41
  42   DESTDIR="$pkgdir" cmake --install build
  43   rm -r "$pkgdir"/{etc,usr/{include,lib,share}} # Provided by libakonadi
  44 }