gupnp-igd/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Eric Bélanger <eric@archlinux.org>
   3
   4 pkgname=gupnp-igd
   5 pkgver=1.2.0
   6 pkgrel=3
   7 pkgdesc="A library to handle UPnP IGD port mapping"
   8 url="https://wiki.gnome.org/Projects/GUPnP"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(gupnp)
  12 makedepends=(gobject-introspection git gtk-doc meson)
  13 options=(debug)
  14 _commit=a0aafc79ac8e258f849cdb2924cb11ec9162d0c5  # tags/1.2.0-correct^0
  15 source=("git+https://gitlab.gnome.org/GNOME/gupnp-igd.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/-correct//;s/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25
  26   # GUPnP 1.6
  27   git cherry-pick -n 649b7100339c57531a8e31f69220f8e17f0860e0 \
  28                      79a1e4cf8c256132978a1d8ab718c8ad132386de
  29 }
  30
  31 build() {
  32   arch-meson $pkgname build -D gtk_doc=true
  33   meson compile -C build
  34 }
  35
  36 check() {
  37   # No multicast in our containers?
  38   meson test -C build --print-errorlogs || :
  39 }
  40
  41 package() {
  42   depends+=(libg{lib,object,io}-2.0.so libg{ssdp,upnp}-1.6.so)
  43   provides+=(libgupnp-igd-1.0.so)
  44
  45   meson install -C build --destdir "$pkgdir"
  46 }
  47
  48 # vim:set sw=2 sts=-1 et: