python-dbusmock/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=python-dbusmock
   4 pkgver=0.28.6
   5 pkgrel=2
   6 pkgdesc="Mock D-Bus objects for tests"
   7 url="https://github.com/martinpitt/python-dbusmock"
   8 arch=(any)
   9 license=(LGPL3)
  10 depends=(python-dbus python-gobject)
  11 makedepends=(python-setuptools python-setuptools-scm git)
  12 _commit=276f54de0f653e8a37b0d0392450df3f57b0a746  # tags/0.28.6^0
  13 source=("git+https://github.com/martinpitt/python-dbusmock#commit=$_commit"
  14         0001-Fix-OBEX-PullAll-after-pathlib-conversion.patch)
  15 sha256sums=('SKIP'
  16             'd259cbecb464ad5ea782f43ca630062ffa03feb6017825a3b7ac235d910ba798')
  17
  18 # Suppress local version
  19 export SETUPTOOLS_SCM_PRETEND_VERSION="${pkgver%%+*}"
  20
  21 pkgver() {
  22   cd $pkgname
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd $pkgname
  28   git apply -3 ../0001-Fix-OBEX-PullAll-after-pathlib-conversion.patch
  29 }
  30
  31 build() {
  32   cd $pkgname
  33   python setup.py build
  34 }
  35
  36 package() {
  37   cd $pkgname
  38   python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  39 }
  40
  41 # vim:set sw=2 sts=-1 et: