qt6-datavis3d/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3
   4 pkgname=qt6-datavis3d
   5 _qtver=6.4.0
   6 pkgver=${_qtver/-/}
   7 pkgrel=1
   8 arch=(x86_64)
   9 url='https://www.qt.io'
  10 license=(GPL3 LGPL3 FDL custom)
  11 pkgdesc='Qt6 Data Visualization module'
  12 depends=(qt6-base)
  13 makedepends=(cmake ninja qt6-declarative)
  14 optdepends=('qt6-declarative: QML bindings')
  15 groups=(qt6)
  16 options=(debug)
  17 _pkgfn=${pkgname/6-/}-everywhere-src-$_qtver
  18 source=(https://download.qt.io/official_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
  19 sha256sums=('0db40038457da5638da8253e70578d6d8799fdb673d4de7bffb3260d6848050d')
  20
  21 build() {
  22   cmake -B build -S $_pkgfn -G Ninja \
  23     -DCMAKE_MESSAGE_LOG_LEVEL=STATUS
  24   cmake --build build
  25 }
  26
  27 package() {
  28   DESTDIR="$pkgdir" cmake --install build
  29
  30   install -d "$pkgdir"/usr/share/licenses
  31   ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
  32 }