gn/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2
   3 pkgname=gn
   4 pkgver=0.2088.5a004f94
   5 _commit=5a004f9427a050c6c393c07ddb85cba8ff3849fa
   6 pkgrel=1
   7 pkgdesc="Meta-build system that generates build files for Ninja"
   8 arch=('x86_64')
   9 url="https://gn.googlesource.com/gn/"
  10 license=('BSD')
  11 depends=('gcc-libs')
  12 makedepends=('clang' 'ninja' 'python' 'git')
  13 source=(git+https://gn.googlesource.com/gn#commit=$_commit)
  14 sha256sums=('SKIP')
  15
  16 pkgver() {
  17   cd $pkgname
  18   echo 0.$(git rev-list --count initial-commit..).$(git rev-parse --short=8 HEAD)
  19 }
  20
  21 build() {
  22   cd $pkgname
  23   ./build/gen.py
  24   ninja -C out
  25 }
  26
  27 check() {
  28   cd $pkgname
  29   ./out/gn_unittests
  30 }
  31
  32 package() {
  33   cd $pkgname
  34   install -D out/gn "$pkgdir/usr/bin/gn"
  35   install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" docs/*
  36   install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  37
  38   mkdir -p "$pkgdir/usr/share/vim/vimfiles"
  39   cp -r misc/vim/{autoload,ftdetect,ftplugin,syntax} \
  40     "$pkgdir/usr/share/vim/vimfiles/"
  41   install -Dm644 -t "$pkgdir/usr/share/emacs/site-lisp" misc/emacs/gn-mode.el
  42 }
  43
  44 # vim:set ts=2 sw=2 et: