lirc/trunk/PKGBUILD

   1 # Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
   2 # Contributor: Paul Mattal <paul@archlinux.org>
   3
   4 pkgname=lirc
   5 _pkgver=0.10.2
   6 [[ $_pkgver =~ [a-z]$ ]] && pkgver="${_pkgver:0:-1}.${_pkgver: -1}" || pkgver="$_pkgver"
   7 pkgrel=3
   8 epoch=1
   9 pkgdesc="Linux Infrared Remote Control utilities"
  10 arch=('x86_64')
  11 url="https://www.lirc.org/"
  12 license=('GPL')
  13 depends=('alsa-lib' 'libx11' 'libftdi' 'libusb-compat')
  14 makedepends=('help2man' 'alsa-lib' 'libx11' 'libxslt' 'python' 'python-setuptools'
  15              'python-yaml' 'systemd')
  16 optdepends=('python: for lirc-setup, irdb-get and pronto2lirc'
  17             'python-gobject: for lirc-setup and irdb-get'
  18             'python-yaml: for lirc-setup and irdb-get')
  19 provides=('lirc-utils')
  20 conflicts=('lirc-utils')
  21 replaces=('lirc-utils')
  22 backup=('etc/lirc/lirc_options.conf' 'etc/lirc/lircd.conf' 'etc/lirc/lircmd.conf')
  23 source=("https://prdownloads.sourceforge.net/${pkgname}/${pkgname}-${_pkgver}.tar.bz2"
  24         lirc.logrotate
  25         lirc.tmpfiles)
  26 sha256sums=('3d44ec8274881cf262f160805641f0827ffcc20ade0d85e7e6f3b90e0d3d222a'
  27             'bd13ca00e30d85ff9166c03b8f7a20195ef89794e66d7e54f04ba1d014a73e7d'
  28             'b8eb6ff2a542a9a3b20fe259fe36aece941db8d309598d2eeb1815b779e2f838')
  29
  30 build() {
  31   cd lirc-${_pkgver}
  32
  33   ./configure \
  34     --prefix=/usr \
  35     --sbindir=/usr/bin \
  36     --sysconfdir=/etc \
  37     --localstatedir=/var \
  38     --enable-devinput \
  39     --enable-uinput
  40   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  41   make
  42 }
  43
  44 package() {
  45   cd lirc-${_pkgver}
  46
  47   make DESTDIR="${pkgdir}" install
  48
  49   install -Dm644 "${srcdir}"/lirc.tmpfiles "${pkgdir}"/usr/lib/tmpfiles.d/lirc.conf
  50   install -Dm644 "${srcdir}"/lirc.logrotate "${pkgdir}"/etc/logrotate.d/lirc
  51
  52   rmdir "${pkgdir}"/var/{run/lirc/,run/}
  53 }