meson/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   3 # Contributor: Anatol Pomozov <anatol dot pomozov at gmail>
   4
   5 pkgname=meson
   6 pkgver=1.1.0
   7 pkgrel=1
   8 pkgdesc="High productivity build system"
   9 url="https://mesonbuild.com/"
  10 arch=(any)
  11 license=(Apache)
  12 depends=(
  13   ninja
  14   python-tqdm
  15   python-typing_extensions
  16 )
  17 makedepends=(
  18   python-build
  19   python-installer
  20   python-setuptools
  21   python-wheel
  22 )
  23 checkdepends=(
  24   boost
  25   clang
  26   cmake
  27   cuda
  28   cython
  29   doxygen
  30   gcc-fortran
  31   gcc-objc
  32   git
  33   gmock
  34   gnustep-base
  35   gobject-introspection
  36   graphviz
  37   gtest
  38   gtk-doc
  39   gtk-sharp-2
  40   gtk3
  41   gtkmm3
  42   hotdoc
  43   itstool
  44   java-environment=8
  45   ldc
  46   libelf
  47   libwmf
  48   llvm
  49   mercurial
  50   mono
  51   nasm
  52   netcdf-fortran
  53   openmpi
  54   openssh
  55   protobuf
  56   python-gobject
  57   python-pytest-xdist
  58   qt5-base
  59   qt5-tools
  60   rust
  61   rust-bindgen
  62   sdl2
  63   vala
  64   valgrind
  65   vulkan-validation-layers
  66   wxgtk3
  67 )
  68 source=(
  69   https://github.com/mesonbuild/meson/releases/download/$pkgver/meson-$pkgver.tar.gz{,.asc}
  70   meson-reference-$pkgver.3::https://github.com/mesonbuild/meson/releases/download/$pkgver/meson-reference.3
  71   meson-reference-$pkgver.json::https://github.com/mesonbuild/meson/releases/download/$pkgver/reference_manual.json
  72   0001-Skip-broken-tests.patch
  73   arch-meson
  74 )
  75 b2sums=('149dedc0e49b72682fa053f27f9a6c2543362539861b4b79ce65ecf4d913e221ac2d63f3b9aa350bd7622851c73be418b804ae1131dd27607eb01218e0204a5e'
  76         'SKIP'
  77         '6f8ec9ccee50e8e33c8c289bae0f33887dc998b5753c373afddc050fa2561172f34ec573f701ed1c5c1715fabcaec2daf5d1979709546816a3813396f34178d5'
  78         'afc89e9f7c8c0af12ab86c7030c17d045eb1b0758ea813d86fc88f83963795a6a9abe9a45e11829f15f5c7daf49fcc0238c31881060d16e2a0e93197f9215e1d'
  79         '742e2c16c6c464e939f68ec7f58951836a75a0fc0170ada25826e7dbc7191bd289f66bfe683941a5ff98d102fd54aeda2c407e9d2ab4276cf607a82ab948093b'
  80         '801ad7689aabd2861c760d6001ce2e84c3d5aaed867b087bc1699e7c15d914ee26c9d855999f389d28b4765f081523a1468755768bc0163185f132e157ecced1')
  81 validpgpkeys=(
  82   19E2D6D9B46D8DAA6288F877C24E631BABB1FE70  # Jussi Pakkanen <jpakkane@gmail.com>
  83 )
  84
  85 prepare() {
  86   cd $pkgname-$pkgver
  87   patch -Np1 -i ../0001-Skip-broken-tests.patch
  88 }
  89
  90 build() {
  91   cd $pkgname-$pkgver
  92   python -m build --wheel --no-isolation
  93 }
  94
  95 check() (
  96   cd $pkgname-$pkgver
  97   export LC_CTYPE=en_US.UTF-8 CPPFLAGS= CFLAGS= CXXFLAGS= LDFLAGS=
  98   ./run_tests.py --failfast
  99 )
 100
 101 package() {
 102   cd $pkgname-$pkgver
 103   python -m installer --destdir="$pkgdir" dist/*.whl
 104
 105   install -d "$pkgdir/usr/share/vim/vimfiles"
 106   cp -rt "$pkgdir/usr/share/vim/vimfiles" data/syntax-highlighting/vim/*/
 107
 108   install -Dm644 data/shell-completions/bash/* -t "$pkgdir/usr/share/bash-completion/completions"
 109   install -Dm644 data/shell-completions/zsh/*  -t "$pkgdir/usr/share/zsh/site-functions"
 110
 111   install -Dm644 ../meson-reference-$pkgver.3    "$pkgdir/usr/share/man/man3/meson-reference.3"
 112   install -Dm644 ../meson-reference-$pkgver.json "$pkgdir/usr/share/doc/$pkgname/reference_manual.json"
 113
 114   install -D ../arch-meson -t "$pkgdir/usr/bin"
 115 }
 116
 117 # vim:set sw=2 sts=-1 et: