totem/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=totem
   5 pkgver=43.0
   6 pkgrel=2
   7 pkgdesc="Movie player for the GNOME desktop based on GStreamer"
   8 url="https://wiki.gnome.org/Apps/Videos"
   9 arch=(x86_64)
  10 license=(GPL2 custom)
  11 depends=(totem-plparser iso-codes libpeas grilo gsettings-desktop-schemas
  12          python-gobject gnome-desktop gst-plugins-base gst-plugins-good
  13          gst-plugins-bad gst-plugin-gtk libhandy libportal-gtk3)
  14 makedepends=(docbook-xsl gobject-introspection git appstream-glib gtk-doc meson
  15              yelp-tools)
  16 checkdepends=(xorg-server-xvfb)
  17 optdepends=('gst-plugins-ugly: Extra media codecs'
  18             'gst-libav: Extra media codecs'
  19             'grilo-plugins: Media discovery')
  20 provides=(libtotem.so)
  21 conflicts=(totem-plugin)
  22 replaces=(totem-plugin)
  23 groups=(gnome)
  24 _commit=7bb879e1f6746ca19f99629794e918cdbbd06008  # tags/43.0^0
  25 source=("git+https://gitlab.gnome.org/GNOME/totem.git#commit=$_commit"
  26         "git+https://gitlab.gnome.org/GNOME/libgd.git")
  27 sha256sums=('SKIP'
  28             'SKIP')
  29
  30 pkgver() {
  31   cd totem
  32   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  33 }
  34
  35 prepare() {
  36   cd totem
  37
  38   git submodule init
  39   git submodule set-url subprojects/libgd "$srcdir/libgd"
  40   git -c protocol.file.allow=always submodule update
  41 }
  42
  43 build() {
  44   local meson_options=(
  45     -D enable-gtk-doc=true
  46   )
  47
  48   arch-meson totem build "${meson_options[@]}"
  49   meson compile -C build
  50 }
  51
  52 check() {
  53   dbus-run-session xvfb-run -s '-nolisten local' \
  54     meson test -C build --print-errorlogs
  55 }
  56
  57 package() {
  58   meson install -C build --destdir "$pkgdir"
  59   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 totem/COPYING
  60 }
  61
  62 # vim:set sw=2 sts=-1 et: