libpst/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgbase=libpst
   5 pkgname=(libpst libpst-docs)
   6 pkgver=0.6.76
   7 pkgrel=7
   8 pkgdesc="Outlook .pst file converter"
   9 url="https://www.five-ten-sg.com/libpst/"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(gcc-libs libgsf)
  13 makedepends=(python boost)
  14 options=(debug)
  15 source=(https://www.five-ten-sg.com/libpst/packages/${pkgbase}-${pkgver}.tar.gz
  16         python310.patch)
  17 sha256sums=('3d291beebbdb48d2b934608bc06195b641da63d2a8f5e0d386f2e9d6d05a0b42'
  18             '8bd2cf189719fa98831b26b28ed68098a82fe6f31a1e23d8576faa27fc4e819f')
  19
  20 prepare() {
  21   cd $pkgbase-$pkgver
  22   patch -Np1 -i ../python310.patch
  23 }
  24
  25 build() {
  26   cd $pkgbase-$pkgver
  27   ./configure --prefix=/usr --mandir=/usr/share/man \
  28       --disable-static --enable-libpst-shared --disable-dii
  29   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  30   make
  31 }
  32
  33 package_libpst() {
  34   optdepends=('boost-libs: for libpst python interface')
  35   provides=(libpst.so)
  36
  37   make -C $pkgbase-$pkgver DESTDIR="$pkgdir" install
  38
  39   mkdir -p doc/usr/share
  40   mv {"$pkgdir",doc}/usr/share/doc
  41 }
  42
  43 package_libpst-docs() {
  44   pkgdesc+=" (documentation)"
  45   depends=()
  46
  47   mv doc/* "$pkgdir"
  48 }
  49
  50 # vim:set sw=2 et: