gtksourceview4/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3 # Contributor: Ionut Biru <ibiru@archlinux.org>
   4
   5 pkgname=gtksourceview4
   6 pkgver=4.8.4
   7 pkgrel=1
   8 pkgdesc="A text widget adding syntax highlighting and more to GNOME"
   9 url="https://wiki.gnome.org/Projects/GtkSourceView"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(gtk3 libxml2)
  13 makedepends=(gobject-introspection vala gtk-doc glade yelp-tools git meson)
  14 checkdepends=(xorg-server-xvfb)
  15 provides=(libgtksourceview-${pkgver%%.*}.so)
  16 _commit=7fd3adb3134bbec167167bb6400e018e4f781eb9  # tags/4.8.4^0
  17 source=("git+https://gitlab.gnome.org/GNOME/gtksourceview.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd gtksourceview
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd gtksourceview
  27 }
  28
  29 build() {
  30   local meson_options=(
  31     -D glade_catalog=true
  32     -D gtk_doc=true
  33   )
  34
  35   arch-meson gtksourceview build "${meson_options[@]}"
  36   meson compile -C build
  37 }
  38
  39 check() {
  40   dbus-run-session xvfb-run -s '-nolisten local' \
  41     meson test -C build --print-errorlogs
  42 }
  43
  44 package() {
  45   meson install -C build --destdir "$pkgdir"
  46 }
  47
  48 # vim:set sw=2 sts=-1 et: