libcloudproviders/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Maxime Gauduin <alucryd@archlinux.org>
   3 # Contributor: Fina Wilke <fina@felinira.net>
   4
   5 pkgname=libcloudproviders
   6 pkgver=0.3.1+r8+g3a229ee
   7 pkgrel=1
   8 pkgdesc="DBus API that allows cloud storage sync clients to expose their services"
   9 url="https://gitlab.gnome.org/World/libcloudproviders"
  10 arch=(x86_64)
  11 license=(LGPL3)
  12 depends=(glib2)
  13 makedepends=(git gobject-introspection meson vala gtk-doc)
  14 _commit=3a229eee7dbdf7159fafab2f797e90fd89fdd05c  # master
  15 source=("git+https://gitlab.gnome.org/World/libcloudproviders.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25 }
  26
  27 build() {
  28   arch-meson $pkgname build -D enable-gtk-doc=true
  29   meson compile -C build
  30 }
  31
  32 check() {
  33   meson test -C build --print-errorlogs
  34 }
  35
  36 package() {
  37   meson install -C build --destdir "$pkgdir"
  38 }
  39
  40 # vim:set sw=2 sts=-1 et: