libfido2/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Karol Babioch <karol@babioch.de>
   3
   4 pkgname=libfido2
   5 pkgver=1.13.0
   6 pkgrel=1
   7 pkgdesc='Library functionality for FIDO 2.0, including communication with a device over USB'
   8 url='https://developers.yubico.com/libfido2/'
   9 arch=('x86_64')
  10 license=('BSD')
  11 depends=('glibc' 'openssl' 'libcbor' 'libcbor.so' 'hidapi' 'systemd-libs'  'libudev.so' 'zlib')
  12 makedepends=('cmake' 'systemd')
  13 provides=('libfido2.so')
  14 source=("https://developers.yubico.com/libfido2/Releases/libfido2-${pkgver}.tar.gz"{,.sig})
  15 sha512sums=('90f8452cee4c9cc72241478e697c5c692ccff5ab27752f2f296c3623ee297d1f80a85a359b4d0656c67790084c116aac921894e762eb52d3a79056e5014c03e7'
  16             'SKIP')
  17 b2sums=('506e0ecf89825e313fbcb0de59ef0b1a3aab483013f959b391448da0600979780ae76807639231ab8a60eead039471bba707073ec4e259b611d67031ac7713f1'
  18         'SKIP')
  19 validpgpkeys=(
  20   'EE90AE0D19774C8386628FAAB428949EF7914718' # pedro martelletto <pedro@yubico.com>
  21   '1D7308B0055F5AEF36944A8F27A9C24D9588EA0F' # Aveen Ismail <aveen.ismail@yubico.com>
  22   '7FBB6186957496D58C751AC20E777DD85755AA4A' # Konstantinos Georgantas <kostas@yubico.com>
  23   '78D997D53E9C0A2A205392ED14A19784723C9988' # Ludvig Michaelsson <ludvig.michaelsson@yubico.com>
  24 )
  25
  26 build() {
  27   cd ${pkgname}-${pkgver}
  28   # do not use bundled udev rules superseded by systemd
  29   cmake -B build \
  30     -DCMAKE_INSTALL_PREFIX=/usr \
  31     -DCMAKE_INSTALL_LIBDIR=lib \
  32     -DCMAKE_BUILD_TYPE=Release \
  33     -DCMAKE_C_FLAGS="${CFLAGS} ${CPPFLAGS}" \
  34     -Wno-dev \
  35     -S .
  36   make -C build VERBOSE=1
  37 }
  38
  39 package() {
  40   cd ${pkgname}-${pkgver}
  41   make -C build DESTDIR="${pkgdir}" install
  42   install -Dm 644 NEWS README.adoc -t "${pkgdir}/usr/share/doc/${pkgname}"
  43   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  44 }
  45
  46 # vim: ts=2 sw=2 et: