libgdiplus/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Daniel Isenmann <daniel@archlinux.org>
   3
   4 pkgname=libgdiplus
   5 pkgver=5.6.1
   6 pkgrel=4
   7 url='https://www.mono-project.com/docs/gui/libgdiplus/'
   8 pkgdesc='Open Source Implementation of the GDI+ API'
   9 arch=('x86_64')
  10 license=('MPL' 'LGPL')
  11 depends=('libtiff' 'libjpeg' 'libpng' 'cairo' 'giflib' 'libgif.so' 'glib2'
  12          'libexif' 'zlib' 'freetype2')
  13 source=(https://github.com/mono/libgdiplus/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
  14 sha256sums=('deff863023950b1d1de7e47e44fc31c8ba39cfc06334737261965f697b2ad312')
  15 sha512sums=('fe6a798da6ad194d4e1d3ce2ebb71a43d3f2f3d198bdf053e8a03e861c81c1c838f3d5d60cfde6b1d6f662fb7f9c2192a9acc89c30a65999e841f4ad7b180baf')
  16
  17 prepare() {
  18   cd ${pkgname}-${pkgver}
  19   autoreconf -fiv
  20 }
  21
  22 build() {
  23   cd ${pkgname}-${pkgver}
  24   ./configure \
  25     --prefix=/usr \
  26     --with-cairo=system
  27   make
  28 }
  29
  30 check() {
  31   cd ${pkgname}-${pkgver}
  32   make check
  33 }
  34
  35 package() {
  36   cd ${pkgname}-${pkgver}
  37   make DESTDIR="${pkgdir}" install
  38   install -Dm 644 NEWS README TODO AUTHORS ChangeLog -t "${pkgdir}/usr/share/doc/${pkgname}"
  39 }
  40
  41 # vim: ts=2 sw=2 et: