libgnome-keyring/trunk/PKGBUILD

   1 #Maintainer: Jan De Groot <jgc@archlinux.org>
   2
   3 pkgname=libgnome-keyring
   4 pkgver=3.12.0+13+g4f8ab73
   5 pkgrel=3
   6 pkgdesc="GNOME keyring client library (deprecated)"
   7 url="https://gitlab.gnome.org/GNOME/libgnome-keyring"
   8 arch=(x86_64)
   9 license=(GPL LGPL)
  10 depends=(dbus glib2 libgcrypt)
  11 makedepends=(intltool gobject-introspection vala git gnome-common)
  12 optdepends=('org.freedesktop.secrets: secret storage backend')
  13 _commit=4f8ab73d19e5621b06102dc29ad880e74aeec573  # master
  14 source=("git+https://gitlab.gnome.org/GNOME/libgnome-keyring.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24   NOCONFIGURE=1 ./autogen.sh
  25 }
  26
  27 build() {
  28   cd "$pkgname"
  29   ./configure --prefix=/usr --sysconfdir=/etc \
  30       --localstatedir=/var --disable-static \
  31       --libexecdir=/usr/lib --enable-gtk-doc
  32   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  33   make
  34 }
  35
  36 package() {
  37   cd "$pkgname"
  38   make DESTDIR="$pkgdir" install
  39 }