libgssglue/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Tom Gundersen <teg@jklm.no>
   3 # Contributor: Tobias Powalowski <tpowa@archlinux.org>
   4
   5 pkgname=libgssglue
   6 pkgver=0.7
   7 pkgrel=1
   8 pkgdesc="Library exporting a gssapi interface to call gssapi routines in other libraries"
   9 arch=(x86_64)
  10 url="https://gitlab.com/gsasl/libgssglue/"
  11 license=(BSD)
  12 depends=(glibc)
  13 provides=(libgssglue.so)
  14 backup=(etc/gssapi_mech.conf)
  15 source=(https://gitlab.com/gsasl/$pkgname/-/archive/$pkgname-$pkgver/$pkgname-$pkgname-$pkgver.tar.gz)
  16 sha512sums=('6f3b2bec37fec376fcdbf804593c01d6ba35541e482956f454583e6cd9e623f4d0f85ee75302621c38abe67c7675a39312bc25522985253482aa7012b8b6688e')
  17 b2sums=('ade4c5eaf642e79090d84688f4c4e2abd07b1cdc955fafaf439c1453dc64e25fd2a7433b5330dd70e8a1559b1270af5f2029ab3027f53b1d01c05e6a7532489c')
  18
  19 prepare() {
  20   cd $pkgname-$pkgname-$pkgver
  21   touch ChangeLog
  22   autoreconf -fiv
  23 }
  24
  25 build() {
  26   cd $pkgname-$pkgname-$pkgver
  27   ./configure --prefix=/usr
  28   make
  29 }
  30
  31 package() {
  32   make DESTDIR="$pkgdir/" install -C $pkgname-$pkgname-$pkgver
  33   install -vDm 644 $pkgname-$pkgname-$pkgver/doc/gssapi_mech.conf -t "$pkgdir/etc/"
  34   install -vDm 644 $pkgname-$pkgname-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
  35   install -vDm 644 $pkgname-$pkgname-$pkgver/{AUTHORS,README,NEWS} -t "$pkgdir/usr/share/doc/$pkgname/"
  36 }