libtool/trunk/PKGBUILD

   1 # Maintainer: Giancarlo Razzolini <grazzolini@archlinux.org>
   2 # Maintainer: Frederik Schwan <freswa at archlinux dot org>
   3 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   4 # Contributor: Allan McRae <allan@archlinux.org>
   5 # Contributor: judd <jvinet@zeroflux.org>
   6
   7 # NOTE: requires rebuilt with each new gcc version
   8
   9 pkgname=libtool
  10 _commit=1ec8fa28dcb29500d485c136db28315671ec4c3b
  11 pkgver=2.4.7+4+g1ec8fa28
  12 pkgrel=3
  13 _gccver=13.1.1
  14 pkgdesc='A generic library support script'
  15 arch=(x86_64)
  16 url='https://www.gnu.org/software/libtool'
  17 license=(GPL)
  18 depends=(sh tar glibc)
  19 makedepends=("gcc>=$_gccver" git help2man)
  20 checkdepends=(gcc-fortran)
  21 provides=("libltdl=$pkgver" "libtool-multilib=$pkgver")
  22 conflicts=(libltdl libtool-multilib)
  23 replaces=(libltdl libtool-multilib)
  24 source=(git+https://git.savannah.gnu.org/git/libtool.git#commit=$_commit
  25         git+https://git.savannah.gnu.org/git/gnulib.git
  26         gnulib-bootstrap::git+https://github.com/gnulib-modules/bootstrap.git
  27         no_hostname.patch
  28         disable-lto-link-order2.patch
  29         grep_3.8_fix.patch)
  30 sha256sums=('SKIP'
  31             'SKIP'
  32             'SKIP'
  33             '693aabb24a6e7ce21fe0b5d14394e19edcb8476663b5afa4463f9fa0df24d946'
  34             'b6dce6681f223b18a90614edbcdeb00f228abd1216e22c4bd07285321cd2ceb7'
  35             '0a31d3ed91d97a18e17942c85018899c0233493a54c885f4c133454de522ef50')
  36
  37 pkgver() {
  38   cd libtool
  39   git describe --tags | sed 's/-/+/g;s/^v//'
  40 }
  41
  42 prepare() {
  43   cd libtool
  44
  45   patch -Np1 -i "${srcdir}"/no_hostname.patch
  46
  47   # test 67 is broken with lto
  48   # this patch removes the -flto flag for this very test
  49   # adapt when -ffat-lto-objects is enabled by Arch
  50   patch -Np1 -i "${srcdir}"/disable-lto-link-order2.patch
  51
  52   # test 66 is broken with grep 3.8
  53   # see https://bugzilla.opensuse.org/show_bug.cgi?id=1203097
  54   patch -Np1 -i "${srcdir}"/grep_3.8_fix.patch
  55
  56   git submodule init
  57   git config --local submodule.gnulib.url "${srcdir}"/gnulib
  58   git config --local submodule.gl-mod/bootstrap.url "${srcdir}"/gnulib-bootstrap
  59   git -c protocol.file.allow=always submodule update
  60
  61   ./bootstrap
  62 }
  63
  64 build() {
  65   cd libtool
  66   ./configure --prefix=/usr lt_cv_sys_lib_dlsearch_path_spec="/usr/lib /usr/lib32"
  67   make
  68 }
  69
  70 check() {
  71   cd libtool
  72   make check gl_public_submodule_commit=
  73 }
  74
  75 package() {
  76   cd libtool
  77   make DESTDIR="$pkgdir" install
  78 }