libwpe/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=libwpe
   4 pkgver=1.14.1
   5 pkgrel=2
   6 pkgdesc="General-purpose library for WPE WebKit"
   7 url="https://wpewebkit.org"
   8 arch=(x86_64)
   9 license=(custom)
  10 depends=(
  11   gcc-libs
  12   libegl
  13   libxkbcommon
  14 )
  15 makedepends=(
  16   git
  17   mesa
  18   meson
  19 )
  20 provides=(libwpe-1.0.so)
  21 _commit=40a382f1a02db5a57b0e510ddfc9498f2458be83  # tags/1.14.1^0
  22 source=("git+https://github.com/WebPlatformForEmbedded/libwpe?signed#commit=$_commit")
  23 b2sums=('SKIP')
  24 validpgpkeys=('5AA3BC334FD7E3369E7C77B291C559DBE4C9123B') # Adrián Pérez de Castro <aperez@igalia.com>
  25
  26 pkgver() {
  27   cd libwpe
  28   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  29 }
  30
  31 prepare() {
  32   cd libwpe
  33 }
  34
  35 build() {
  36   arch-meson libwpe build
  37   meson compile -C build
  38 }
  39
  40 check() {
  41   meson test -C build --print-errorlogs
  42 }
  43
  44 package() {
  45   meson install -C build --destdir "$pkgdir"
  46   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 libwpe/COPYING
  47 }
  48
  49 # vim:set sw=2 sts=-1 et: