qt6-quick3d/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   4
   5 pkgname=qt6-quick3d
   6 _qtver=6.5.0
   7 pkgver=${_qtver/-/}
   8 pkgrel=2
   9 arch=(x86_64)
  10 url='https://www.qt.io'
  11 license=(GPL3)
  12 pkgdesc='Qt module and API for defining 3D content in Qt Quick'
  13 depends=(qt6-quicktimeline)
  14 makedepends=(cmake ninja qt6-shadertools assimp)
  15 optdepends=('qt6-shadertools: for shadergen' 'assimp: assimp import plugin')
  16 groups=(qt6)
  17 _pkgfn=${pkgname/6-/}-everywhere-src-$_qtver
  18 source=(https://download.qt.io/official_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
  19 sha256sums=('9b590429ca98b5cc8cec4df2efa3775e9f11ed8260d123e95f3c0fc37f3772a5')
  20
  21 build() {
  22   cmake -B build -S $_pkgfn -G Ninja \
  23     -DCMAKE_MESSAGE_LOG_LEVEL=STATUS
  24   cmake --build build
  25 }
  26
  27 package() {
  28   DESTDIR="$pkgdir" cmake --install build
  29
  30   install -d "$pkgdir"/usr/share/licenses
  31   ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
  32 }