xdg-user-dirs-gtk/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=xdg-user-dirs-gtk
   4 pkgver=0.11
   5 pkgrel=1
   6 pkgdesc="Creates user dirs and asks to relocalize them"
   7 url="https://gitlab.gnome.org/GNOME/xdg-user-dirs-gtk"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(gtk3 xdg-user-dirs)
  11 makedepends=(intltool git)
  12 groups=(gnome)
  13 options=(debug)
  14 _commit=cf2a85fa5370aa7cdf36d1c8259ca89d3d737ef9  # tags/0.11^0
  15 source=("git+https://gitlab.gnome.org/GNOME/xdg-user-dirs-gtk.git#commit=$_commit"
  16         show-in-mate.diff)
  17 sha256sums=('SKIP'
  18             '80bd751b9bfc95e06775da31ff1ae32417bfca2df3b9e063d478b056834224f3')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27   git apply -3 ../show-in-mate.diff
  28   autoreconf -fvi
  29 }
  30
  31 build() {
  32   cd $pkgname
  33   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  34     --disable-more-warnings
  35   make
  36 }
  37
  38 package() {
  39   cd $pkgname
  40   make DESTDIR="$pkgdir" install
  41 }
  42
  43 # vim:set sw=2 sts=-1 et: