c-ares/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Dave Reisner <dreisner@archlinux.org>
   3 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   4 # Contributor: Jeff Mickey <jeff@archlinux.org>
   5 # Contributor: Alexander Fehr <pizzapunk gmail com>
   6
   7 pkgname=c-ares
   8 pkgver=1.18.1
   9 pkgrel=1
  10 pkgdesc="A C library for asynchronous DNS requests"
  11 arch=('x86_64')
  12 url="https://c-ares.haxx.se/"
  13 license=('MIT')
  14 depends=('glibc')
  15 makedepends=('cmake')
  16 provides=('libcares.so')
  17 source=("https://github.com/${pkgname}/${pkgname}/releases/download/${pkgname//-}-${pkgver//./_}/${pkgname}-${pkgver}.tar.gz"{,.asc})
  18 sha512sums=('1276ec0799916019f8c0af6b55a139701bd15e0ca4a00811d07963893978bc96c107b980f0fd49f81aa70bc8b3b8cd671195ba357c390772d4c2c5643c50c5a5'
  19             'SKIP')
  20 b2sums=('c03a572726c6bbb24a3e4773673d0c87f4833bb9582aed57a424eea8c965beb6e232f502b61922b124d37403d91ebfefe0db7373673fc22e0d752c4e5036eb07'
  21         'SKIP')
  22 validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2') # Daniel Stenberg <daniel@haxx.se>
  23
  24 build() {
  25   cd "$pkgname-$pkgver"
  26   cmake -DCMAKE_INSTALL_PREFIX=/usr \
  27         -DCMAKE_BUILD_TYPE='None' \
  28         -Wno-dev \
  29         -B build \
  30         -S .
  31   make VERBOSE=1 -C build
  32 }
  33
  34 package() {
  35   cd "$pkgname-$pkgver"
  36   make DESTDIR="${pkgdir}" install -C build
  37   install -vDm 644 "LICENSE.md" -t "${pkgdir}/usr/share/licenses/${pkgname}/"
  38   install -vDm 644 {AUTHORS,CHANGES,{CONTRIBUTING,README}.md,RELEASE-NOTES} \
  39     -t "${pkgdir}/usr/share/doc/${pkgname}/"
  40 }