gnome-todo/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-todo
   4 pkgver=41.0+r106+gebc68374
   5 pkgrel=1
   6 pkgdesc="Task manager for GNOME"
   7 url="https://wiki.gnome.org/Apps/Todo"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(evolution-data-server libpeas python gtk4 libportal-gtk4 libadwaita)
  11 makedepends=(gobject-introspection appstream-glib git meson yelp-tools)
  12 groups=(gnome-extra)
  13 options=(debug)
  14 _commit=ebc683746c705faa7c080aa96eecb83e523a8c15  # master
  15 source=("git+https://gitlab.gnome.org/GNOME/gnome-todo.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/^GNOME_TODO_//;s/_/./g;s/[^-]*-g/r&/;s/-/+/g'
  21
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26 }
  27
  28 build() {
  29   arch-meson $pkgname build
  30   meson compile -C build
  31 }
  32
  33 check() (
  34   glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/$pkgname/data}"
  35   export GSETTINGS_SCHEMA_DIR
  36
  37   meson test -C build --print-errorlogs
  38 )
  39
  40 package() {
  41   meson install -C build --destdir "$pkgdir"
  42 }
  43
  44 # vim:set sw=2 et: