libpcap/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@mirantis.com>
   3 # Contributor: Thomas Bächler <thomas@archlinux.org>
   4
   5 pkgname=libpcap
   6 pkgver=1.10.1
   7 pkgrel=2
   8 pkgdesc='A system-independent interface for user-level packet capture'
   9 arch=(x86_64)
  10 url='https://www.tcpdump.org/'
  11 license=(BSD)
  12 depends=(glibc libnl sh)
  13 makedepends=(bluez-libs dbus)
  14 provides=(libpcap.so)
  15 options=(debug)
  16 source=("https://www.tcpdump.org/release/${pkgname}-${pkgver}.tar.gz"{,.sig})
  17 sha512sums=('56c314f19c2b857742bf8abcb1e78066986aaa95cec339b75a3c8b70a9fa2b5167da98708352f9ec97a1cea2700cfb4e040bda108d58ac46cec9b7deab88d171'
  18             'SKIP')
  19 b2sums=('0ec028e5d026a97b92ba6f23f88daf36b827eee08a752a0162fbabd1b5a2a70141ec403b6ff26dc3eb25ca5c6630c9c2f60f05b33161770da3d5e829c4eecdc6'
  20         'SKIP')
  21 validpgpkeys=('1F166A5742ABB9E0249A8D30E089DEF1D9C15D0D') # The Tcpdump Group
  22
  23 prepare() {
  24   cd $pkgname-$pkgver
  25   autoreconf -fiv
  26 }
  27
  28 build() {
  29   cd $pkgname-$pkgver
  30   ./configure --prefix=/usr \
  31               --enable-ipv6 \
  32               --enable-bluetooth \
  33               --enable-usb \
  34               --with-libnl
  35   make
  36 }
  37
  38 package() {
  39   depends+=(libdbus-1.so)
  40
  41   cd $pkgname-$pkgver
  42   make DESTDIR="$pkgdir" install
  43   install -vDm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
  44   install -vDm 644 {CHANGES,{CONTRIBUTING,README}.md} -t "$pkgdir/usr/share/doc/$pkgname/"
  45 }