mkinitcpio-busybox/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Giancarlo Razzolini <grazzolini@archlinux.org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Dave Reisner <dreisner@archlinux.org>
   4 # Contributor: Thomas Bächler <thomas@archlinux.org>
   5
   6 pkgname=mkinitcpio-busybox
   7 pkgver=1.35.0
   8 pkgrel=1
   9 pkgdesc='Base initramfs tools'
  10 arch=(x86_64)
  11 url="https://www.busybox.net/"
  12 license=(GPL)
  13 depends=(glibc libxcrypt)
  14 options=(!buildflags)
  15 source=(https://busybox.net/downloads/busybox-$pkgver.tar.bz2{,.sig}
  16         config)
  17 sha256sums=('faeeb244c35a348a334f4a59e44626ee870fb07b6884d68c10ae8bc19f83a694'
  18             'SKIP'
  19             'fe7bd3c7150c25a8ad24190d305a012b84766f34847a7efc7126e19261b0c711')
  20 validpgpkeys=('C9E9416F76E610DBD09D040F47B70C55ACC9965B') # Denis Vlasenko <vda.linux@googlemail.com>
  21
  22 prepare() {
  23   cd "busybox-$pkgver"
  24
  25   local safeflags="-march=${CARCH/_/-} -mtune=generic -Os -pipe -fno-strict-aliasing"
  26
  27   # use make oldconfig for updating the config file
  28   sed 's|^\(CONFIG_EXTRA_CFLAGS\)=.*|\1="'"$safeflags"'"|' "$srcdir/config" > .config
  29 }
  30
  31 build() {
  32   # reproducible build
  33   export KCONFIG_NOTIMESTAMP=1
  34   make -C "busybox-$pkgver"
  35 }
  36
  37 package() {
  38   install -Dm755 "$srcdir/busybox-$pkgver/busybox" "$pkgdir/usr/lib/initcpio/busybox"
  39 }