whois/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: Giovanni Scafora <giovanni@archlinux.org>
   4 # Contributor: Tom Newsom <Jeepster@gmx.co.uk>
   5
   6 pkgname=whois
   7 pkgver=5.5.13
   8 pkgrel=1
   9 pkgdesc="Intelligent WHOIS client"
  10 arch=('x86_64')
  11 url="https://github.com/rfc1036/whois"
  12 license=('GPL')
  13 depends=('libidn2')
  14 makedepends=('perl' 'git')
  15 backup=('etc/whois.conf')
  16 source=(git+https://github.com/rfc1036/whois.git#tag=v$pkgver?signed)
  17 sha256sums=('SKIP')
  18 validpgpkeys=('6791403B68AE2690517C42EAE6FFF1E38DC968B0') # Marco d'Itri <md@linux.it>
  19
  20 build() {
  21   cd "$srcdir/$pkgname"
  22   make \
  23     CONFIG_FILE=/etc/whois.conf \
  24     CFLAGS="$CFLAGS $CPPFLAGS" \
  25     HAVE_ICONV=1
  26 }
  27
  28 package() {
  29   cd "$srcdir/$pkgname"
  30   make prefix=/usr BASEDIR="$pkgdir" install-whois
  31   install -Dm644 whois.conf -t "$pkgdir/etc"
  32 }
  33
  34 # vim:set ts=2 sw=2 et: