keyutils/trunk/PKGBUILD

   1 # Maintainer: Stéphane Gaudreault <stephane@archlinux.org>
   2 # Contributor: Tobias Powalowski <tpowa@archlinux.org>
   3
   4 pkgname=keyutils
   5 _tag='5678a1aae8834b5c16b5ed7dc72ef8836a29e122' # git rev-parse v${pkgver}
   6 pkgver=1.6.3
   7 pkgrel=2
   8 pkgdesc='Linux Key Management Utilities'
   9 arch=('x86_64')
  10 url='https://www.kernel.org/'
  11 license=('GPL2' 'LGPL2.1')
  12 depends=('glibc' 'sh')
  13 makedepends=('git')
  14 provides=('libkeyutils.so')
  15 backup=('etc/request-key.conf')
  16 validpgpkeys=('A86E54B0D5E1B4E0AB7C640FFBB7576BA7CB0B6B') # David Howells <dhowells@redhat.com>
  17 source=("git+https://git.kernel.org/pub/scm/linux/kernel/git/dhowells/keyutils.git#tag=${_tag}?signed"
  18         'request-key.conf.patch' 'reproducible.patch')
  19 sha256sums=('SKIP'
  20             '203c602c61ed94ccd423a0a453d74143d678c641a9a4486367576ee8af2cb8d6'
  21             '7bb7400b2b8c8f0288c86ec9191f8964a1e682745a204013d5fc7c2e1a253d8e')
  22
  23 prepare() {
  24   cd ${pkgname}
  25   # fix paths of binaries in /etc/request-key.conf
  26   patch -Np0 -i ../request-key.conf.patch
  27
  28   # make keyutils reproducible
  29   patch -Np1 -i ../reproducible.patch
  30 }
  31
  32 build() {
  33   cd ${pkgname}
  34   make CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" SBINDIR='/usr/bin' BINDIR='/usr/bin'
  35 }
  36
  37 package() {
  38   cd ${pkgname}
  39   make DESTDIR="${pkgdir}" SBINDIR='/usr/bin' BINDIR='/usr/bin' LIBDIR='/usr/lib' USRLIBDIR='/usr/lib' install
  40 }