libodfgen/trunk/PKGBUILD

   1 # Maintainer: AndyRTR <andyrtr@archlinux.org>
   2 # Contributor:  Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Yue
   4
   5 pkgname=libodfgen
   6 pkgver=0.1.8
   7 pkgrel=2
   8 pkgdesc='Library for generating documents in Open Document Format'
   9 arch=('x86_64')
  10 url='https://sourceforge.net/p/libwpd/wiki/libodfgen/'
  11 license=('MPL')
  12 depends=('zlib' 'librevenge' 'libxml2')
  13 makedepends=('libwpg' 'libetonyek' 'doxygen')
  14 source=(https://sourceforge.net/projects/libwpd/files/libodfgen/libodfgen-$pkgver/$pkgname-$pkgver.tar.xz)
  15 sha1sums=('9b36d313e64c6ce1026485d521fbdeff7f47594c')
  16 sha256sums=('55200027fd46623b9bdddd38d275e7452d1b0ff8aeddcad6f9ae6dc25f610625')
  17
  18 build() {
  19   cd $pkgname-$pkgver
  20   ./configure --prefix=/usr --disable-werror
  21   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  22   make
  23 }
  24
  25 check() {
  26   cd $pkgname-$pkgver
  27   make check
  28 }
  29
  30 package() {
  31   cd $pkgname-$pkgver
  32   make DESTDIR="$pkgdir" install
  33 }