libsigc++-3.0/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Tom Newsom <Jeepster@gmx.co.uk>
   4
   5 pkgbase=libsigc++-3.0
   6 pkgname=(libsigc++-3.0 libsigc++-3.0-docs)
   7 pkgver=3.4.0
   8 pkgrel=1
   9 pkgdesc="Callback Framework for C++"
  10 url="https://libsigcplusplus.github.io/libsigcplusplus/"
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(gcc-libs)
  14 makedepends=(git meson mm-common)
  15 options=(!emptydirs)
  16 _commit=e88e319aa50df010320dd15e7c802f92752dc8dc  # tags/3.4.0^0
  17 source=("git+https://github.com/libsigcplusplus/libsigcplusplus#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd libsigcplusplus
  22   git describe --tags | sed 's/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd libsigcplusplus
  27 }
  28
  29 build() {
  30   arch-meson libsigcplusplus build -D maintainer-mode=true
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package_libsigc++-3.0() {
  39   provides=(libsigc-3.0.so)
  40
  41   meson install -C build --destdir "$pkgdir"
  42
  43   # Split -docs
  44   mkdir -p docs/usr/share
  45   mv -t docs/usr/share "$pkgdir"/usr/share/{devhelp,doc}
  46 }
  47
  48 package_libsigc++-3.0-docs() {
  49   pkgdesc+=" (documentation)"
  50   depends=()
  51   options=(!strip)
  52
  53   mv -t "$pkgdir" docs/*
  54 }