man-db/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2 # Contributor: Sergej Pupykin <sergej@aur.archlinux.org>
   3
   4 pkgname=man-db
   5 pkgver=2.11.2
   6 pkgrel=1
   7 pkgdesc="A utility for reading man pages"
   8 arch=('x86_64')
   9 url="https://gitlab.com/cjwatson/man-db"
  10 license=('GPL' 'LGPL')
  11 depends=( 'bash' 'gdbm' 'zlib' 'groff' 'libpipeline' 'less' 'libseccomp')
  12 makedepends=('po4a')
  13 optdepends=('gzip') # covered by virtual "base" package
  14 backup=('etc/man_db.conf')
  15 conflicts=('man')
  16 provides=('man')
  17 replaces=('man')
  18 options=('debug')
  19 install=${pkgname}.install
  20 source=(https://savannah.nongnu.org/download/man-db/$pkgname-$pkgver.tar.xz{,.asc}
  21         # fallback should be used within first 24h after a release
  22         #https://download-mirror.savannah.gnu.org/releases/man-db/$pkgname-$pkgver.tar.xz{,.asc}
  23         convert-mans
  24 )
  25 validpgpkeys=('AC0A4FF12611B6FCCF01C111393587D97D86500B') # Colin Watson <cjwatson@debian.org>
  26 sha512sums=('edb71cce7249c7b7f2f524e92f682047a77ed9ae8856763dfc8e18e239444651ff4c505e697f5a8b1be3b85678e714fbb1a520defe72a4eb685bc2cecc0e4391'
  27             'SKIP'
  28             '0b159285da20008f0fc0afb21f1eaebd39e8df5b0594880aa0e8a913b656608b8d16bb8d279d9e62d7aae52f62cb9b2fc49e237c6711f4a5170972b38d345535')
  29
  30 build() {
  31   cd ${pkgname}-${pkgver}
  32   ./configure --prefix=/usr \
  33     --sbindir=/usr/bin \
  34     --sysconfdir=/etc \
  35     --libexecdir=/usr/lib \
  36     --with-systemdsystemunitdir=/usr/lib/systemd/system \
  37     --with-snapdir=/var/lib/snapd/snap \
  38     --with-db=gdbm \
  39     --disable-setuid \
  40     --enable-cache-owner=root \
  41     --enable-mandirs=GNU \
  42     --with-sections="1 1p n l 8 3 3p 0 0p 2 3type 5 4 9 6 7"
  43   make
  44 }
  45
  46 check() {
  47   cd ${pkgname}-${pkgver}
  48   make check
  49 }
  50
  51 package() {
  52   cd ${pkgname}-${pkgver}
  53   make DESTDIR=${pkgdir} install
  54
  55   # part of groff pkg
  56   rm -f ${pkgdir}/usr/bin/zsoelim
  57
  58   # script from LFS to convert manpages, see
  59   # http://www.linuxfromscratch.org/lfs/view/6.4/chapter06/man-db.html
  60   install -D -m755 ${srcdir}/convert-mans  ${pkgdir}/usr/bin/convert-mans
  61
  62   install -d -m755 ${pkgdir}/usr/lib/systemd/system/timers.target.wants
  63   ln -s ../man-db.timer ${pkgdir}/usr/lib/systemd/system/timers.target.wants/man-db.timer
  64 }