python-urwid/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Daniel Isenmann <daniel@archlinux.org>
   3 # Contributor: Sergej Pupykin <sergej@aur.archlinux.org>
   4 # Contributor: Douglas Soares de Andrade <dsandrade@gmail.com>
   5
   6 _name=urwid
   7 pkgname=python-urwid
   8 pkgver=2.1.2.r56.gabc098c
   9 # somewhere past 2.1.2 as there has not been a release in years to have Python 3.11 support without bricking dependents
  10 # https://github.com/urwid/urwid/issues/511
  11 # https://github.com/urwid/urwid/issues/548
  12 # https://github.com/urwid/urwid/issues/550
  13 _commit=abc098c3400220b51aeb6fec14175e1bfa1f8bfb
  14 pkgrel=1
  15 pkgdesc='Curses-based user interface library'
  16 url='https://urwid.org/'
  17 arch=('x86_64')
  18 license=('LGPL')
  19 depends=(
  20   'glibc'
  21   'python'
  22   'python-typing-extensions'
  23 )
  24 makedepends=(
  25   'git'
  26   'python-build'
  27   'python-installer'
  28   'python-setuptools'
  29   'python-wheel'
  30 )
  31 source=(
  32   git+https://github.com/$_name/$_name.git#commit=$_commit
  33 )
  34 sha256sums=('SKIP')
  35 sha512sums=('SKIP')
  36
  37 pkgver() {
  38   cd $_name
  39   git describe --long --abbrev=7 | sed 's/^release-//;s/\([^-]*-g\)/r\1/;s/-/./g'
  40 }
  41
  42 build() {
  43   cd $_name
  44   python -m build --wheel --no-isolation
  45 }
  46
  47 check() {
  48   cd $_name
  49   python -m unittest discover -vs $_name/tests
  50 }
  51
  52 package() {
  53   cd $_name
  54   python -m installer --destdir="$pkgdir" dist/*.whl
  55   rm -rv "${pkgdir}"/usr/lib/python*/site-packages/urwid/tests
  56 }
  57
  58 # vim: ts=2 sw=2 et: