ostree/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   3 # Contributor: Mirco Tischler <mt-ml at gmx dot de>
   4
   5 pkgname=ostree
   6 _commit=ecd00a3e1977c9193ea0b27669234fa5669dfe7c  # tags/v2023.2
   7 pkgver=2023.2
   8 pkgrel=1
   9 pkgdesc="Operating system and container binary deployment and upgrades"
  10 url="https://ostreedev.github.io/ostree/"
  11 arch=(x86_64)
  12 license=(custom:LGPL2)
  13 depends=(
  14   bash
  15   fuse3
  16   gcc-libs
  17   glibc
  18   libgpg-error
  19   libsodium
  20   sh
  21   util-linux
  22   zlib
  23 )
  24 makedepends=(
  25   avahi
  26   curl
  27   e2fsprogs
  28   git
  29   glib2
  30   gobject-introspection
  31   gpgme
  32   gtk-doc
  33   libarchive
  34   libsoup
  35   libxslt
  36   mkinitcpio
  37   openssl
  38   python
  39   systemd
  40   xz
  41 )
  42 checkdepends=(
  43   cpio
  44   elfutils
  45   gjs
  46   parallel
  47   python-yaml
  48   syslinux
  49 )
  50 provides=(libostree-1.so)
  51 source=(
  52   git+https://github.com/ostreedev/ostree#tag=$_commit
  53   git+https://github.com/mendsley/bsdiff
  54   git+https://gitlab.gnome.org/GNOME/libglnx.git
  55   $pkgname-2023.1-use_fuse3.patch
  56 )
  57 b2sums=('SKIP'
  58         'SKIP'
  59         'SKIP'
  60         'cfff162120f70995e18ec56454711501391b97456e2a0f34643c9d2a9c2b50b4d76afc2e2fc50ea28e8a773c618215d6cb855b96663f69dc5cc93bc5766f3f28')
  61 # upstream ticket about chain of trust:
  62 # https://github.com/ostreedev/ostree/issues/2349
  63 validpgpkeys=('1CEC7A9DF7DA85ABEF843DC0A866D7CCAE087291') # Colin Walters <walters@redhat.com>
  64
  65 prepare() {
  66   cd $pkgname
  67
  68   # Fixes for GLib 2.76
  69   git cherry-pick -n 376c9d7effa01fa020711a3f12829fe9b18b8bca \
  70                      813c439352297622e74a288aadf3cd700d19bc2f
  71
  72   # use fusemount3 (fuse3)
  73   git apply -3 ../$pkgname-2023.1-use_fuse3.patch
  74
  75   # remove failing test: https://github.com/ostreedev/ostree/issues/2790
  76   sed -e '/test-signed-pull-summary.sh/d' -i Makefile-tests.am
  77
  78   git submodule init
  79   git submodule set-url bsdiff "$srcdir/bsdiff"
  80   git submodule set-url libglnx "$srcdir/libglnx"
  81   git -c protocol.file.allow=always submodule update
  82
  83   NOCONFIGURE=1 ./autogen.sh
  84 }
  85
  86 build() {
  87   local configure_options=(
  88     --prefix=/usr
  89     --sysconfdir=/etc
  90     --localstatedir=/var
  91     --sbindir=/usr/bin
  92     --libexecdir=/usr/lib
  93     --disable-static
  94     --enable-experimental-api
  95     --enable-gtk-doc
  96     --with-builtin-grub2-mkconfig
  97     --with-curl
  98     --with-dracut
  99     --with-ed25519-libsodium
 100     --with-mkinitcpio
 101     --with-openssl
 102   )
 103
 104   cd $pkgname
 105   ./configure "${configure_options[@]}"
 106   # prevent overlinking due to libtool
 107   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
 108   make
 109 }
 110
 111 check() {
 112   make check -k -C $pkgname
 113 }
 114
 115 package() {
 116   depends+=(
 117     avahi libavahi-client.so libavahi-common.so libavahi-glib.so
 118     curl libcurl.so
 119     glib2 libgio-2.0.so libglib-2.0.so libgobject-2.0.so
 120     gpgme libgpgme.so
 121     libarchive libarchive.so
 122     libsoup libsoup-2.4.so
 123     openssl libcrypto.so
 124     systemd-libs libsystemd.so
 125     xz liblzma.so
 126   )
 127
 128   make DESTDIR="$pkgdir" install -C $pkgname
 129   install -vDm 644 $pkgname/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
 130 }