pavucontrol/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   3 # Contributor: Corrado Primier <bardo@aur.archlinux.org>
   4 # Contributor: William Rea <sillywilly@gmail.com>
   5
   6 pkgname=pavucontrol
   7 pkgver=5.0+r61+gee77d86
   8 pkgrel=2
   9 epoch=1
  10 pkgdesc="PulseAudio Volume Control"
  11 url="https://freedesktop.org/software/pulseaudio/pavucontrol/"
  12 arch=(x86_64)
  13 license=(GPL)
  14 depends=(gtkmm3 libsigc++ libcanberra json-glib)
  15 makedepends=(meson lynx git)
  16 checkdepends=(tidy)
  17 optdepends=("pulseaudio: Audio backend")
  18 options=(debug)
  19 _commit=ee77d86eed3c35f9f7a1f2e2da385d4b526d77a1  # master
  20 source=("git+https://gitlab.freedesktop.org/pulseaudio/pavucontrol.git#commit=$_commit")
  21 sha256sums=('SKIP')
  22
  23 pkgver() {
  24   cd pavucontrol
  25   git describe --tags | sed 's/^v//;s/[^-]*-g/r&/;s/-/+/g'
  26 }
  27
  28 prepare() {
  29   cd pavucontrol
  30 }
  31
  32 build() {
  33   arch-meson pavucontrol build
  34   meson compile -C build
  35 }
  36
  37 check() {
  38   meson test -C build --print-errorlogs
  39 }
  40
  41 package() {
  42   meson install -C build --destdir "$pkgdir"
  43 }