conntrack-tools/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Sébastien Luttringer
   2 # Contributor: Valere Monseur <valere_monseur@hotmail.com>
   3 # Contributor: Alessandro Sagratini <ale_sagra@hotmail.com>
   4 # Contributor: Kevin Edmonds <edmondskevin@hotmail.com>
   5
   6 pkgname=conntrack-tools
   7 pkgver=1.4.7
   8 pkgrel=1
   9 pkgdesc='Userspace tools to interact with the Netfilter connection tracking system'
  10 arch=('x86_64')
  11 url='https://www.netfilter.org/projects/conntrack-tools/'
  12 license=('GPL2')
  13 makedepends=('systemd' 'libtirpc')
  14 depends=('glibc' 'libnetfilter_conntrack' 'libnetfilter_cttimeout'
  15          'libnetfilter_cthelper' 'libnetfilter_queue' 'libmnl' 'systemd-libs'
  16          'libnfnetlink')
  17 backup=('etc/conntrackd.conf')
  18 validpgpkeys=('37D964ACC04981C75500FB9BD55D978A8A1420E4') # Netfilter Core Team
  19 source=("https://www.netfilter.org/projects/$pkgname/files/$pkgname-$pkgver.tar.bz2"{,.sig}
  20         'conntrackd.service')
  21 install=$pkgname.install
  22 sha256sums=('099debcf57e81690ced57f516b493588a73518f48c14d656f823b29b4fc24b5d'
  23             'SKIP'
  24             '8ffdd2130be8f5a80c80b1784f18f857d4af0acb9a392d67c1f8c7212436d85e')
  25
  26 prepare() {
  27   sed -i -e 's,/etc/conntrackd/,/etc/,' -e 's,/var/lock/,/run/lock/,' \
  28     $pkgname-$pkgver/include/conntrackd.h
  29 }
  30
  31
  32 build() {
  33   cd $pkgname-$pkgver
  34   ./configure  \
  35     LIBNETFILTER_CTHELPER_CFLAGS='-I /usr/include/tirpc/' \
  36     --prefix=/usr \
  37     --sysconfdir=/etc \
  38     --sbindir=/usr/bin \
  39     --enable-systemd
  40   make
  41 }
  42
  43 package() {
  44   # install binaries
  45   cd $pkgname-$pkgver
  46   make DESTDIR="$pkgdir" install
  47   # systemd
  48   cd "$pkgdir"
  49   install -D -m 644 "$srcdir/conntrackd.service" usr/lib/systemd/system/conntrackd.service
  50   # install empty configuration files
  51   install -D -m 644 /dev/null etc/conntrackd.conf
  52 }
  53
  54 # vim:set ts=2 sw=2 et: