icu/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Andreas Radke <andyrtr@archlinux.org>
   2 # Contributor: Art Gramlich <art@gramlich-net.com>
   3
   4 pkgname=icu
   5 pkgver=72.1
   6 pkgrel=2
   7 pkgdesc="International Components for Unicode library"
   8 arch=(x86_64)
   9 url="https://icu.unicode.org"
  10 license=('custom:icu')
  11 depends=('gcc-libs' 'sh')
  12 makedepends=('python')
  13 provides=(libicu{data,i18n,io,test,tu,uc}.so)
  14 options=('debug')
  15 source=(https://github.com/unicode-org/icu/releases/download/release-${pkgver//./-}/${pkgname}4c-${pkgver//./_}-src.tgz{,.asc})
  16 # https://github.com/unicode-org/icu/releases/download/release-71-1/SHASUM512.txt
  17 sha512sums=('848c341b37c0ff077e34a95d92c6200d5aaddd0ee5e06134101a74e04deb08256a5e817c8aefab020986abe810b7827dd7b2169a60dacd250c298870518dcae8'
  18             'SKIP')
  19 #validpgpkeys=('BA90283A60D67BA0DD910A893932080F4FB419E3') #  "Steven R. Loomis (filfla-signing) <srloomis@us.ibm.com>"
  20 #validpgpkeys+=('9731166CD8E23A83BEE7C6D3ACA5DBE1FD8FABF1') #  "Steven R. Loomis (ICU Project) <srl@icu-project.org>"
  21 #validpgpkeys+=('FFA9129A180D765B7A5BEA1C9B432B27D1BA20D7') # "Fredrik Roubert <fredrik@roubert.name>"
  22 #validpgpkeys+=('E4098B78AFC94394F3F49AA903996C7C83F12F11') # "keybase.io/srl295 <srl295@keybase.io>"
  23 #validpgpkeys+=('4569BBC09DA846FC91CBD21CE1BBA44593CF2AE0') # "Steven R. Loomis (codesign-qormi) <srloomis@us.ibm.com>"
  24 #validpgpkeys=('0E51E7F06EF719FBD072782A5F56E5AFA63CCD33') #"Craig Cornelius (For use with ICU releases) <ccornelius@google.com>"
  25 validpgpkeys=('3DA35301A7C330257B8755754058F67406EAA6AB') # Craig Cornelius <ccornelius@google.com>
  26
  27 build() {
  28   cd icu/source
  29   ./configure --prefix=/usr \
  30         --sysconfdir=/etc \
  31         --mandir=/usr/share/man \
  32         --sbindir=/usr/bin
  33   make
  34 }
  35
  36 check() {
  37   cd icu/source
  38   make -k check
  39 }
  40
  41 package() {
  42   cd icu/source
  43   make -j1 DESTDIR="${pkgdir}" install
  44
  45   # Install license
  46   install -Dm644 "${srcdir}"/icu/LICENSE "${pkgdir}"/usr/share/licenses/icu/LICENSE
  47 }