leafpad/trunk/PKGBUILD

   1 # Maintainer: Aaron Griffin <aaron@archlinux.org>
   2 # Contributor: Link Dupont <link@subpop.net>
   3
   4 pkgname=leafpad
   5 pkgver=0.8.19
   6 pkgrel=2
   7 pkgdesc='A notepad clone for GTK+ 2.0'
   8 arch=('x86_64')
   9 url='http://tarot.freeshell.org/leafpad/'
  10 license=('GPL')
  11 depends=('gtk2')
  12 makedepends=('intltool')
  13 validpgpkeys=('05B80A3FFAF8FED36ADC7A31EE109F4A0F184934') # Tarot Osuji <tarot@sdf.org>
  14 source=("https://download.savannah.gnu.org/releases/${pkgname}/${pkgname}-${pkgver}.tar.gz"{,.sig}
  15         '0001-fix-format-security-error-from-gcc.patch')
  16 sha256sums=('07d3f712f4dbd0a33251fd1dee14e21afdc9f92090fc768c11ab0ac556adbe97'
  17             'SKIP'
  18             '2b99426837e0a78077931e33bbfac280b238e0d170366c09e62bf98770e837dc')
  19
  20 prepare() {
  21   cd "${srcdir}/${pkgname}-${pkgver}"
  22
  23   patch -Np1 < ../0001-fix-format-security-error-from-gcc.patch
  24 }
  25
  26 build() {
  27   cd "${srcdir}/${pkgname}-${pkgver}"
  28
  29   ./configure \
  30     --prefix=/usr \
  31     --enable-chooser
  32   make
  33 }
  34
  35 package() {
  36   cd "${srcdir}/${pkgname}-${pkgver}"
  37
  38   make DESTDIR="${pkgdir}" install
  39   echo 'StartupNotify=true' >> "${pkgdir}/usr/share/applications/leafpad.desktop"
  40 }