pcre/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Sébastien "Seblu" Luttringer
   2 # Contributor: Allan McRae <allan@archlinux.org>
   3 # Contributor: Eric Belanger <eric@archlinux.org>
   4 # Contributor: John Proctor <jproctor@prium.net>
   5
   6 pkgname=pcre
   7 pkgver=8.45
   8 pkgrel=3
   9 pkgdesc='A library that implements Perl 5-style regular expressions'
  10 arch=('x86_64')
  11 url='https://www.pcre.org/'
  12 license=('BSD')
  13 depends=('gcc-libs' 'readline' 'zlib' 'bzip2' 'bash')
  14 provides=(libpcre{,16,32,posix,cpp}.so)
  15 options=(debug)
  16 source=("https://sourceforge.net/projects/pcre/files/$pkgname/$pkgver/$pkgname-$pkgver.tar.bz2"{,.sig})
  17 sha512sums=('91bff52eed4a2dfc3f3bfdc9c672b88e7e2ffcf3c4b121540af8a4ae8c1ce05178430aa6b8000658b9bb7b4252239357250890e20ceb84b79cdfcde05154061a'
  18             'SKIP')
  19 validpgpkeys=('45F68D54BBE23FB3039B46E59766E084FB0F43D8')  # Philip Hazel <ph10@hermes.cam.ac.uk>
  20
  21 build() {
  22   cd $pkgname-$pkgver
  23   ./configure \
  24     --prefix=/usr \
  25     --enable-unicode-properties \
  26     --enable-pcre16 \
  27     --enable-pcre32 \
  28     --enable-jit \
  29     --enable-pcregrep-libz \
  30     --enable-pcregrep-libbz2 \
  31     --enable-pcretest-libreadline
  32   make
  33 }
  34
  35 check() {
  36   cd $pkgname-$pkgver
  37   make -j1 check
  38 }
  39
  40 package() {
  41   cd $pkgname-$pkgver
  42   make DESTDIR="$pkgdir" install
  43
  44   install -Dm644 LICENCE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  45 }
  46
  47 # vim:set sw=2 sts=-1 et: