qt6-multimedia/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3
   4 pkgbase=qt6-multimedia
   5 pkgname=(qt6-multimedia qt6-multimedia-gstreamer qt6-multimedia-ffmpeg)
   6 _qtver=6.4.1
   7 pkgver=${_qtver/-/}
   8 pkgrel=1
   9 arch=(x86_64)
  10 url='https://www.qt.io'
  11 license=(GPL3 LGPL3 FDL custom)
  12 pkgdesc='Classes for audio, video, radio and camera functionality'
  13 makedepends=(cmake ninja qt6-declarative qt6-shadertools gst-plugins-base libpulse ffmpeg qt6-quick3d)
  14 groups=(qt6)
  15 options=(debug)
  16 _pkgfn=${pkgname/6-/}-everywhere-src-$_qtver
  17 source=(https://download.qt.io/official_releases/qt/${pkgver%.*}/$_qtver/submodules/$_pkgfn.tar.xz)
  18 sha256sums=('c086d43a026e6090971fd7a697ef8370c5c455115240609cd08d5e2f840dbaaf')
  19
  20 build() {
  21   cmake -B build -S $_pkgfn -G Ninja \
  22     -DCMAKE_MESSAGE_LOG_LEVEL=STATUS \
  23     -DCMAKE_CXX_FLAGS="$CXXFLAGS -ffat-lto-objects"
  24   cmake --build build
  25 }
  26
  27 package_qt6-multimedia() {
  28   depends=(qt6-base qt6-multimedia-backend)
  29   optdepends=('qt6-declarative: QML bindings'
  30               'qt6-quick3d: for QtQuick3DAudio')
  31
  32   DESTDIR="$pkgdir" cmake --install build
  33 # Split plugins
  34   rm -r "$pkgdir"/usr/lib/qt6/plugins/
  35   rm "$pkgdir"/usr/lib/cmake/Qt6Multimedia/Qt6Q{FFmpeg,Gstreamer}*
  36
  37   install -d "$pkgdir"/usr/share/licenses
  38   ln -s /usr/share/licenses/qt6-base "$pkgdir"/usr/share/licenses/$pkgname
  39 }
  40
  41 package_qt6-multimedia-gstreamer() {
  42   pkgdesc='Gstreamer backend for qt6-multimedia'
  43   depends=(qt6-multimedia gst-plugins-base)
  44   provides=(qt6-multimedia-backend)
  45   groups=()
  46   optdepends=('gst-plugins-good: camera support, additional plugins'
  47               'gst-plugins-bad: camera support, additional plugins'
  48               'gst-plugins-ugly: additional plugins'
  49               'gst-libav: additional plugins')
  50
  51   DESTDIR="$pkgdir" cmake --install build/src/plugins/multimedia/gstreamer
  52 }
  53
  54 package_qt6-multimedia-ffmpeg() {
  55   pkgdesc='FFMpeg backend for qt6-multimedia'
  56   depends=(qt6-multimedia ffmpeg libva)
  57   provides=(qt6-multimedia-backend)
  58   groups=()
  59
  60   DESTDIR="$pkgdir" cmake --install build/src/plugins/multimedia/ffmpeg
  61 }