speex/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jason Chu <jason@archlinux.org>
   3
   4 pkgname=speex
   5 pkgver=1.2.1
   6 pkgrel=1
   7 pkgdesc="A free codec for free speech"
   8 url="https://www.speex.org/"
   9 arch=(x86_64)
  10 license=(BSD)
  11 depends=(gcc-libs libogg speexdsp)
  12 makedepends=(git)
  13 options=(debug)
  14 _commit=5dceaaf3e23ee7fd17c80cb5f02a838fd6c18e01  # tags/Speex-1.2.1^0
  15 source=("git+https://gitlab.xiph.org/xiph/speex.git#commit=$_commit")
  16 b2sums=('SKIP')
  17
  18 pkgver() {
  19   cd speex
  20   git describe --tags | sed 's/^Speex-//;s/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd speex
  25   ./autogen.sh
  26 }
  27
  28 build() {
  29   cd speex
  30   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  31     --enable-binaries \
  32     --disable-static
  33   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  34   make
  35 }
  36
  37 check() {
  38   cd speex
  39   make -k check
  40 }
  41
  42 package() {
  43   depends+=(libogg.so libspeexdsp.so)
  44   provides+=(libspeex.so)
  45
  46   cd speex
  47   make DESTDIR="$pkgdir" install
  48   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
  49 }